*  JieJie Microelectronics P-Spice Model Library
*  Filename	: JMSL0606AU_P v.20210618.txt
*  Product Name      	: JMSL0606AU (PDFN3x3)
*  Configuration:	: Single N-channel Device
*  Data Sheet Rev.	: 1.0
*  Release Date	: June 3, 2021
*  Junction Temp (Tj)	: -40C ~ 150C
******************************************************************************************************
*  This model is designed as a tool to assist end user(s) to evaluate the performance
*  of the particular SGT MOSFET (named above) released by JJMSH(R).  It has been
*  verified for function and timing integrity with the commercially available EDA simulat-
*  ion tools. End-user(s) is/are advised to take the best engineering practice (e.g.
*  bread-boarding, laboratory measurement) for the full evaluation.
*
*  Despite of the best effort on engineering & verification, JieJie Microelectronics Co.,
*  Ltd. ("JJM") does not provide any warranty nor take any liability to the results and
*  their effects whatsoever from the simulation run of this model by the end-user(s).
*  While this model may be updated at appropriate times in the future without prior
*  notice, JJM does not assume the sole responsibility for update. 
*
.subckt JMSL0606AU D G S 
M1 1 2 3 3 NMOS L=1E-006 W=1E-006
Vmonitor D 18 0
RD 18 1 0.0016
RS S 3 1E-006
RG G 17 1.7
CGS 3 G 2E-9
EGD 12 0 2 1 1
Etemp 17 2 VALUE = {(-0.0015*(TEMP-25))+((-5.47718E-6)*(TEMP-25)^2)}
Gtemp 1 3 VALUE = {I(Vmonitor)*((TEMP+273)/(298)-((TEMP+273)/(298))^1.46)}
VFB 14 0 0
FFB 2 1 VFB 1
CGD 13 14 0.63E-9
DDG 15 14 DCGD
R2 12 15 1
D2 15 0 DLIM
DSD 3 D DSUB
RR 13 0 1
D1 12 13 DLIM
Cbreak D 3 Cbreak 2.06039E-9
.MODEL Cbreak CAP (C= 1 VC1 = -0.03499 VC2 = 3.50392E-4)
.model NMOS NMOS
+LEVEL = 3                                        
+VMAX = 1.0752E9               ETA = 1E-4                    
+VTO = 2.37331                 TOX = 8E-10                   NSUB = 3.55E15                
+KP = 201.229                  U0 = 424                      KAPPA = 5.856E-10             
+GAMMA = 0.67319               PHI = 0.545242                THETA = 0.530375              
+BEX = -2.05                   TCV = 4.4E-3                  DELTA = 10.4                  
.model DCGD D
+CJO = 5.31672E-10             VJ = 18.2605                  M = 3.33                      
.model DSUB D
+IS = 1.18256E-10              N = 1.226                     RS = 3.92688E-3               
+BV = 63                                                           
+xti = 5.9                     
.model DLIM D
+IS = 1E-4                     
.ends JMSL0606AU

******************************************************************************************************
*  Copyright (C) 2021 JJM. All rights reserved.
******************************************************************************************************